通達信短買23個買點集合主圖指標公式：

MM1:=5;
MM2:=13;
MM3:=21;
MM4:=34;
MM5:=55;
MM6:=89;
MM7:=144;
MM8:=233;
M5:EMA(C,MM1);
M13:EMA(C,MM2);
M21:EMA(C,MM3);
M34:EMA(C,MM4);
M55:EMA(C,MM5),POINTDOT,LINETHICK2,COLOR3366DD;
M89:EMA(C,MM6),POINTDOT,LINETHICK2,COLOR66FFAA;
M144:EMA(C,MM7),POINTDOT,LINETHICK2,COLOR6633FF;
M233:EMA(C,MM8),POINTDOT,LINETHICK2,COLOR6666FF;
{B1:=BARSLAST(HHV(HIGH,19)=H);}
B1:=CONST(LLV(LOW,19));
B2:=CONST(HHV(HIGH,19));
支撐價:IF(CURRBARSCOUNT<19,B1,DRAWNULL), COLORLIRED,CIRCLEDOT;
阻力價:IF(CURRBARSCOUNT<19,B2,DRAWNULL),COLORLIBLUE,CIRCLEDOT;
{攻擊臨界點}
C1:=C<B2/1.03 AND C>B2/1.05;
C2:=IF(CURRBARSCOUNT=1 AND PERIOD=5,VOL*240/FROMOPEN,DRAWNULL);
C3:=C2/REF(V,1)>=1.5;
C4:=C1 AND C3;
C5:=C2/REF(V,1)>=2;
DRAWTEXT(C4,L,'☆攻擊臨界點'),COLORLIRED;
DRAWTEXT(C4 AND C5,L,'☆頸線位量超'),COLORLIRED;
{旱地拔蔥}
D1:=19;
D2:=BARSLAST(LLV(LOW,D1)=L);
D3:=BARSLAST(C/REF(C,1)>1.09);
D4:=D3-D2;
D5:=D4>=0 AND D4<3;
D6:=FILTER(D5,D1);
D7:=COUNT(C/REF(C,1)>1.05,12)>=9;
DRAWTEXT(D6 OR D7,L,'☆旱地拔蔥'),COLORLICYAN;
D8:=COUNT(D6,3)>0;
D9:=C>M13 AND C<M13*1.02;
DRAWTEXT(D8 AND D9 ,L,'☆厚積薄發(fā)'),COLORLICYAN;
{小陽放量滯漲}
E1:=5; E2:=3;
E3:=C/REF(C,1)>=1 AND C/REF(C,1)<1.02;
E4:=V/REF(V,1)>1;
E5:=COUNT(E3 AND E4,E1)>=E2;
E6:=FILTER(E5,E1);
DRAWTEXT(E6,L,'☆小陽放量滯漲'),COLORLIGREEN;
{輕舟越過萬重山}
F1:=V/CAPITAL*100<3;
F2:=C>M233*1.03 AND C<M233*1.11 AND C/REF(C,1)>1.04 AND REF(C,1)<M233;
F3:=F2 AND F1;
DRAWTEXT(F3,L,'☆輕舟越過萬重山'),COLORLIBLUE;
{空頭強駑之末}
FF1:=M55>M34 AND M34>M13;
FF2:=C<M13*0.8;
FF3:=FF1 AND FF2;
DRAWTEXT(FF3,L,'☆空頭強駑之末'),COLORLIBLUE;
{黃金買點}
G1:=CONST(LLV(LOW,55));
G2:=CONST(HHV(HIGH,55));
G3:=G2-G1;
G4:=C<(G2-G3*0.382)*1.05 AND C>(G2-G3*0.382)*0.98;
G5:=FILTER(G4,10);
DRAWTEXT(G5 AND CURRBARSCOUNT<10,L,'☆黃金買點'),COLORLIBLUE;
{假陰線}
H1:=REF(C,1)/REF(C,2)>1.0985;
H2:=O>REF(H,1) AND O>C;
H3:=V/REF(V,1)>1.3;
H4:=M5>M21;
H5:=C/REF(C,1)>1.01;
H6:=H1 AND H2 AND H3 AND H4 AND H5;
DRAWTEXT(H6,L,'☆假陰線'),COLORLIBLUE;
{直破多頭線}
J1:=M13>M34 AND M34>M55;
J2:=M13>REF(M13,1);
J3:=(M13-M34)>(REF(M13,2)-REF(M34,2));
J4:=C/REF(C,1)<0.97 AND L/M34>0.99 AND L/M34<1.01;
J5:=J1 AND J2 AND J3 AND J4;
J6:=FILTER(J5,10);
DRAWTEXT(J6,L,'☆直破多頭線'),COLORLIBLUE;
{日、周線同處0乖離}
K1:=M13>M34 AND M34>M55;
K2:=MA(C#WEEK,13)>MA(C#WEEK,34) AND MA(C#WEEK,34)>MA(C#WEEK,55);
K3:=C>M13*0.98 AND C<M13*1.03;
K4:=C>MA(C#WEEK,13)*0.98 AND C<MA(C#WEEK,13)*1.03;
K5:=K1 AND K2 AND K3 AND K4;
K6:=FILTER(K5,10);
DRAWTEXT(K6,L,'☆日、周線同處0乖離'),COLORLIBLUE;
{穿越分水嶺}
L1:=COUNT(C>M55,20)<2;
L2:=REF(C,1)<M55 AND C>M55 AND C<M55*1.03 AND C>REF(C,1);
L3:=L1 AND L2;
L4:=FILTER(L3,10);
DRAWTEXT(L4,L,'☆穿越分水嶺'),COLORLIBLUE;
{十全十美}
N1:=M13>M34 AND M34>M55;
N2:=REF(M13,1)>REF(M34,1) AND REF(M34,1)>REF(M55,1);
N3:="MACD.DIF">"MACD.DEA" AND "MACD.DEA">0;
N4:="MACD.MACD"<REF("MACD.MACD",1);
N5:=FILTER(N4,5);
N6:=C<REF(C,1) AND C>M13 AND C<M13*1.02;
N7:=N1 AND N2 AND N3 AND N5 AND N6;
DRAWTEXT(N7,L,'☆十全十美'),COLORLIBLUE;
{扭轉乾坤}
O1:=LAST(COUNT(C/REF(C,1)<0.95,4)>0,5,1);
O2:=C/REF(C,1)>1.07;
O3:=(V=HHV(V,6)) AND O1 AND O2;
O4:=FILTER(O3,5);
DRAWTEXT(O4,L,'☆扭轉乾坤'),COLORLIBLUE;
{寶劍鋒自磨礪出}
P1:=M13>M34 AND M34>M55;
P2:=REF(M13,1)>REF(M34,1) AND REF(M34,1)>REF(M55,1);
P3:=REF(C,1)<M13 AND LAST(COUNT(C<REF(C,1),4)>2,5,1);
P4:=H>M13 AND (H-C)/REF(C,1)*100>=3 AND C>REF(C,1) AND C/REF(C,1)<1.03;
P5:=P1 AND P2 AND P3 AND P4;
P6:=FILTER(P5,5);
DRAWTEXT(P6,L,'☆扭轉乾坤'),COLORLIBLUE;
{平量橫盤}
Q1:=CONST(LLV(L,20));
Q2:=CONST(HHV(H,20));
Q3:=Q2/Q1>1.2;
Q4:=COUNT(C/REF(C,1)>0.985 AND C/REF(C,1)<1.015,4)>=3;
Q5:=COUNT(V/REF(V,1)>=0.9 AND V/REF(V,1)<=1.2,4)>=3;
Q6:=C>M13 AND L<M13 AND C>REF(C,1);
Q7:=FILTER(Q6,5);
DRAWTEXT(Q7,L,'☆平量橫盤'),COLORLIBLUE;
{火箭沖天加速度}
R1:=COUNT(C/REF(C,1)>1.0985,3)=3;
R2:=COUNT(C/REF(C,1)>1.0985,5)=5;
R3:=R1 AND R2;
DRAWTEXT(R3,L,'☆火箭沖天加速度'),COLORLIBLUE;
{萬里長城永不倒}
S1:=(M13>=REF(M13,1)*0.99) OR (M13<=REF(M13,1)*1.01);
S2:=(M34>=REF(M34,1)*0.99) OR (M34<=REF(M34,1)*1.01);
S3:=(M55>=REF(M55,1)*0.99) OR (M55<=REF(M55,1)*1.01);
S4:=C/REF(C,1)>1.07 AND REF(C,1)<M13 AND REF(C,1)<M34 AND REF(C,1)<M55;
S5:=C>M13 AND C>M34 AND C>M55;
S6:=S1 AND S2 AND S3 AND S4 AND S5;
DRAWTEXT(S6,L,'☆萬里長城永不倒'),COLORLIBLUE;
{擎天柱}
T1:=(C-O)/REF(C,1)*100;
DRAWTEXT(T1>12,L,'☆擎天柱'),COLORLIRED;

通達信短買23個買點集合主圖指標公式實例圖解：

通達信短買23個買點集合主圖指標公式